Lazarus fpvectorial library

本文参考自：

https://wiki.freepascal.org/fpvectorial

1.fpvectorial library 简介

FPVectorial 支持读取、修改和写入矢量图像。

它的对应库是 fcl 图像，它与光栅图像一起工作。FPVectorial 附带了一个单元，允许将矢量图像绘制到TFPCustomCanvas，但没有提供将光栅图像转换为矢量图像的例程。

2.支持的文件

FPVectorial 位于Free Pascal 2.3.1+ 目录
fpc/packages/fpvectoral/src 中，单元是 fpvectoral。

各种图像格式的读取器：

• pdfvectorialreader - 读取支持PDF文件，支持压缩，仅读取第一页
• avisocncgcodereader - 从 Aviso CNC 机器读取对 G-Code 的支持
• cdrverialreader - Corel Draw CDR 文件读取器支持的初始工作
• dxfvectorialreader - 对 DXF（AutoCAD使用的图形交换格式）的读取支持
• svgvectorialreader - 读取对 SVG 的支持
• epsvectoralreade r- 对封装 PostScript 的读取支持
• wmfvectorialreader - 对 WMF 的读取支持（Windows图元文件，跨平台！）

各种图像格式的写入程序：

• avisocncgcodewriter - 编写对 Aviso CNC 机器 G-Code 的支持
• svgvectorialwriter - 编写 SVG 支持。支持直线、曲线和文本。支持笔的颜色和宽度。

其他单元：

• fpvtocanvas - 将矢量文档转换为 TFPCustomCanvas 子代（如 TCanvas）。将矢量图像转换为光栅图像
• fpvutils - 不属于fpvectoral的实用函数。
• pdfvrlexico、pdfvrsemantico、pdfvrsintatico、avisozlib - PDF 阅读器中的其他单元，请勿直接使用

3.格式

• PDF

PDF格式由 Adobe 开发，并有完整的文档记录。在内部，PDF只是文本，所以它很容易解析，但文本的部分通常可以压缩。

• CorelDraw

Corel不发布其CorelDraw文件格式的公共文档。关于这种格式的任何信息都取决于逆向工程和猜测。该格式是二进制的，由块树组成。

• SVG

可缩放矢量图形（SVG）是 W3C 的矢量图形标准。它是 Inkscape 的原生格式，并将其数据存储为一个扩展名为 “.svg” 的未压缩 XML 文件。

• DXF

Autodesk AutoCAD 中的图形交换格式。这种格式是文档化的，但文档的质量相当低，缺乏足够的解释。

格式本身相当简单，由文本组成。每个单元由两行组成，第一行是描述数据类型的数字，然后是另一行，其中包含值本身，可能是文本或数字。

其他 DXF 读取库中最常见的问题是，它们不支持更新版本的 AutoCAD 编写的实际 DXF。fpvectoral并非如此，它已在 AutoCAD 2000 和 前的更简单格式中进行了测试。

• WMF

Windows元文件（WMF）格式最初是在 20 世纪 90 年代为 Microsoft Windows 设计的。这些文件可以包含矢量图形和位图组件，并包含一系列绘图命令和参数，这些参数最初直接传递给 Windows 图形设备接口（GDI）；然而，在 fpvectoral 中，它们被转换为图形对象，这使得格式平台独立。

• PostScript

PostScript 是一种图形绘图编程语言，fpvectorial 有一个解释器，可以执行 PostScript 并将其命令转换为内部格式。这是由读取器模块完成的，例如 epsvectoralreader。解释器分为令牌化器和执行器。令牌分为3种类型：过程、ExpressionTokens 和注释。过程位于 PostScript 中的｛..｝块内，在 FPVectorial 中，它们在第一次使用时不标记，而是在第一次执行时标记。在执行标记之前，整个文档在一次运行中标记化，过程除外。PostScript 解释器包含 PostScript 中指定的堆栈和查找字典。

PostScript可以嵌入各种格式，解释器当前支持EPS格式。

• LAS

LAS 是以 ASPRS LASer（LAS）文件格式编码的地理空间数据，存在于版本 1.0、1.1、1.2、1.3 和 1.4 中。截至2011年12月，版本2.0尚未存在。

4.FPVectorial 中的数据类型

FPVectorial包含三种类型的对象列表：路径、文本和实体。

基本上，路径是点的序列，通过这些点可以运行直线和贝塞尔曲线。路径可以是直线、贝塞尔曲线、折线、多边形或这些元素的任意组合。路径的主要特征是，它们可以用于引导称为 CNC 物理执行绘图。在能够在 CNC 机床中执行包含文本或实体的图形之前，需要将这些项目转换为路径。

文本，就像名字所说的那样，是用字体绘制的字符串。

实体是圆、圆弧、椭圆、旋转椭圆等。

5.示例

5.1格式转换

本例加载 PDF，将其转换为 G-Code，并将G-Code写入TStrings

uses
  fpvectorial, pdfvectorialreader, avisocncgcodewriter;

var
  Vec: TvVectorialDocument;
begin
  if dialogoAbrir.Execute() then
  begin
    Vec := TvVectorialDocument.Create;
    try
      Vec.ReadFromFile(dialogoAbrir.FileName, vfPDF);
      Vec.WriteToStrings(synCodigo.Lines, vfGCodeAvisoCNCPrototipoV5);
    finally
      Vec.Free;
    end;
  end;
end;

5.2添加路径、边框线和文本

此示例显示如何添加各种元素。

program fpvwritetest;

{$mode objfpc}{$H+}

uses
  fpvectorial, svgvectorialwriter;

const
  cFormat = vfSVG;
  cExtension = '.svg';
var
  VecDoc: TvVectorialDocument;
  Vec: TvVectorialPage;
begin
  VecDoc := TvVectorialDocument.Create;
  try
    Vec := VecDoc.AddPage();
    // All documents are 10cm x 10cm
    Vec.Width := 100;
    Vec.Height := 100;

    // ...

    // multi_test_1     Combines various elements
    Vec.Clear;
    Vec.StartPath(0, 20);
    Vec.AddLineToPath(30, 30);
    Vec.EndPath();
    Vec.StartPath(0, 0);
    Vec.AddLineToPath(100, 0);
    Vec.AddLineToPath(100, 100);
    Vec.AddLineToPath(0, 100);
    Vec.AddLineToPath(0, 0);
    Vec.EndPath();
    Vec.StartPath(0, 0);
    Vec.AddLineToPath(10, 10);
    Vec.AddBezierToPath(10, 20, 20, 20, 20, 10);
    Vec.AddLineToPath(30, 0);
    Vec.EndPath();
    Vec.AddText(10, 10, 0, '10,10 Some text in english.');
    Vec.AddText(20, 20, 0, '20, 20 Mówi'c, cze's'c, Wlosku, Parabéns.');
    Vec.AddText(30, 30, 0, '30, 30 森林，是一个高密');
    VecDoc.WriteToFile('multi_test_1' + cExtension, cFormat);
  finally
    VecDoc.Free;
  end;
end.

以下是Opera浏览器渲染此示例时的输出：

5.3 添加对齐坐标

可以添加水平坐标：

Vec.AddAlignedDimension(Make2DPoint(100, 50), Make2DPoint(200, 100), Make2DPoint(100, 150), Make2DPoint(200, 150));

或添加垂直坐标：

Vec.AddAlignedDimension(Make2DPoint(50, 250), Make2DPoint(100, 200), Make2DPoint(150, 250), Make2DPoint(150, 200));

5.4将图像渲染到TCanvas

要将矢量图像渲染到 TCanvas 或 TFPCustomCanvas 中，请使用单元 fpvtocanvas 及其例程：

unit fpvtocanvas;
//..
{@@
  This function draws a FPVectorial vectorial image to a TFPCustomCanvas
  descendent, such as TCanvas from the LCL.

  Be careful that by default this routine does not execute coordinate transformations,
  and that FPVectorial works with a start point in the bottom-left corner, with
  the X growing to the right and the Y growing to the top. This will result in
  an image in TFPCustomCanvas mirrored in the Y axis in relation with the document
  as seen in a PDF viewer, for example. This can be easily changed with the
  provided parameters. To have the standard view of an image viewer one could
  use this function like this:

  DrawFPVectorialToCanvas(ASource, ADest, 0, ASource.Height, 1.0, -1.0);
}
procedure DrawFPVectorialToCanvas(ASource: TvVectorialPage;
  ADest: TFPCustomCanvas;
  ADestX: Integer = 0; ADestY: Integer = 0; AMulX: Double = 1.0; AMulY: Double = 1.0);

下面是一个来自 lazarus ccr/application/fpviewer 的示例：

uses fpvtocanvas;

procedure TfrmFPVViewer.btnVisualizeClick(Sender: TObject);
const
  FPVVIEWER_MAX_IMAGE_SIZE = 1000;
  FPVVIEWER_MIN_IMAGE_SIZE = 100;
  FPVVIEWER_SPACE_FOR_NEGATIVE_COORDS = 100;
var
  Vec: TvVectorialDocument;
  CanvasSize: TPoint;
begin
  // First check the in input
  //if not CheckInput() then Exit;

  notebook.PageIndex := 0;

  Drawer.Clear;

  Vec := TvVectorialDocument.Create;
  try
    Vec.ReadFromFile(editFileName.FileName);

    // We need to be robust, because sometimes the document size won't be given
    // also give up drawing everything if we need more then 4MB of RAM for the image
    // and also give some space in the image to allow for negative coordinates
    if Vec.Width * spinScale.Value > FPVVIEWER_MAX_IMAGE_SIZE then CanvasSize.X := FPVVIEWER_MAX_IMAGE_SIZE
    else if Vec.Width < FPVVIEWER_MIN_IMAGE_SIZE then CanvasSize.X := Drawer.Width
    else CanvasSize.X := Round(Vec.Width * spinScale.Value);
    if CanvasSize.X < Drawer.Width then CanvasSize.X := Drawer.Width;

    if Vec.Height * spinScale.Value > FPVVIEWER_MAX_IMAGE_SIZE then CanvasSize.Y := FPVVIEWER_MAX_IMAGE_SIZE
    else  if Vec.Height < FPVVIEWER_MIN_IMAGE_SIZE then CanvasSize.Y := Drawer.Height
    else CanvasSize.Y := Round(Vec.Height * spinScale.Value);
    if CanvasSize.Y < Drawer.Height then CanvasSize.Y := Drawer.Height;

    Drawer.Drawing.Width := CanvasSize.X;
    Drawer.Drawing.Height := CanvasSize.Y;
    Drawer.Drawing.Canvas.Brush.Color := clWhite;
    Drawer.Drawing.Canvas.Brush.Style := bsSolid;
    Drawer.Drawing.Canvas.FillRect(0, 0, Drawer.Drawing.Width, Drawer.Drawing.Height);
    DrawFPVectorialToCanvas(
      Vec.GetPage(0),
      Drawer.Drawing.Canvas,
      FPVVIEWER_SPACE_FOR_NEGATIVE_COORDS,
      Drawer.Drawing.Height - FPVVIEWER_SPACE_FOR_NEGATIVE_COORDS,
      spinScale.Value,
      -1 * spinScale.Value);
    Drawer.Invalidate;
  finally
    Vec.Free;
  end;
end;

6.FPVectorial 中的坐标

需要注意的是，FPVectorial 使用两种不同的坐标系统：左上坐标和左下坐标。TCanvas 使用 Windows API 中的坐标，原点位于左上角，X轴向右延伸，Y轴向下延伸。FPVectorial 除了支持此系统外，还支持另一种绘图格式，该系统是本地的，例如 CAD 软件、Inkscape、Mac OS X API（Carbon和Cocoa）等。在 FPVectoral 中，除了SVG 之外，所有矢量图形格式的原点都位于左下角。X轴向右增长，Y轴向上增长。SVG和所有文本文档格式（如DOCX）的原点位于左上方。

当坐标与 TCanvas 不匹配时，在 TCanvas 和 FPVectorial 之间转换坐标时应小心。要在 TCanvas 和 FPVectorial 之间转换坐标，需要画布的高度。单位 fpvutils 的以下例程可用于执行此转换：

{@@ Converts the coordinate system from a TCanvas to FPVectorial
   The basic difference is that the Y axis is positioned differently and
   points upwards in FPVectorial and downwards in TCanvas.
   The X axis doesn't change. The fix is trivial and requires only the Height of
   the Canvas as extra info.
}
function CanvasCoordsToFPVectorial(AY: Integer; AHeight: Integer):
Integer; inline;
begin
 Result := AHeight - AY;
end;

在文本定位方面也存在差异。在TCanvas 文本输出文本基于文本区域的左上角坐标定位。在 fpvectoral 中，它基于左下角。同样，单元 fpvutils 中有一个方便的例程可以在坐标系之间转换：

{@@
  LCL Text is positioned based on the top-left corner of the text.
  Besides that, one also needs to take the general coordinate change into account too.

  @param ACanvasHeight Should receive TCanvas.Height
  @param ATextHeight   Should receive TFont.Size
}
function CanvasTextPosToFPVectorial(AY: Integer; ACanvasHeight, ATextHeight: Integer): Integer;
begin
  Result := CanvasCoordsToFPVectorial(AY, ACanvasHeight) - ATextHeight;
end;